Viton-B

T0=-3.9;
c=-10.86;
b=104.8;
α[T_]:=10^(c(T-T0)/(b+T-T0));
PowerExpand[Log[10,α[T]]]

Y[T_,f_]:=(10.49 (1+0.1 I)+15.88(1+0.06 I)(I f α[T])^0.64)/(1+0.0063(I f α[T])^0.64);

Y[T,f]

Modulus and Loss Factor Plots with varying temperature

LogPlot[{Re[Y[T,10]],Re[Y[T,100]],Re[Y[T,1000]],Re[Y[T,10000]],Re[Y[T,100000]],Im[Y[T,10]]/Re[Y[T,10]],Im[Y[T,100]]/Re[Y[T,100]],Im[Y[T,1000]]/Re[Y[T,1000]],Im[Y[T,10000]]/Re[Y[T,10000]],Im[Y[T,100000]]/Re[Y[T,100000]]},{T,-50,70},PlotRange->{{-50,70},{.01,10000}},Frame->True,PlotStyle->{Black,Blue,Cyan,Magenta,Red,Black,Blue,Cyan,Magenta,Red},FrameLabel->{"Temperature, C","Complex Modulus, MPa"}]

Reduced Frequency Plots

Compares to Figure 6.18, “Plot of modulus and loss factor versus reduced frequency for Viton-B”, in David I.G. Jones, Handbook of Viscoelastic Vibration Damping, John Wiley & Sons, TA355.J39, 2001.

Clear[EY,eta];
n=10;
nd=11;
fac=10^(1/n);
f1=.01;
fs=Table[f1 fac^i,{i,0,n*nd}];
nf=n nd +1;
EY=Table[{fs[[i]] α[22],Re[Y[22,fs[[i]]]]},{i,1,nf}];
η=Table[{fs[[i]] α[22],Im[Y[22,fs[[i]]]]/Re[Y[22,fs[[i]]]]},{i,1,nf}];

ListLogLogPlot[EY,Joined->True,Frame->True,FrameLabel->{"Reduced Frequency, Hz","Elastic Modulus, MPa"}]

ListLogLogPlot[η,Joined->True,Frame->True,FrameLabel->{"Reduced Frequency, Hz","Loss Factor, MPa"}]

Wicket Plot

Compares to Figure 6.17, “Wicket plot for Viton-B”, in David I.G. Jones, Handbook of Viscoelastic Vibration Damping, John Wiley & Sons, TA355.J39, 2001.

n=10;
nd=7;
fac=10^(1/n);
f1=1;
fs=Table[f1 fac^i,{i,0,n*nd}];
nf=n nd +1;
pts=Table[{Re[Y[22,fs[[i]]]],Im[Y[22,fs[[i]]]]/Re[Y[22,fs[[i]]]]},{i,1,nf}];
ListLogLogPlot[pts,Joined->True,Frame->True,FrameLabel->{"Elastic Modulus, MPa","Loss Factor"}]

Modulus and Loss Factor at a specific frequency and temperature range

The blade-spring of the Quad’s Upper Intermediate Mass (UIM) has a first internal resonance of ~110 Hz. The Non-Magnetic, Blade-spring Damper (NMBD) uses Viton (or Fluorel) as a viscoelastic element in a (broadly tuned) mass-spring damper. The NMBD is assembled, tuned and tested in a lab which is warmer (and less temperature stable) than the LVEA/VEA environments. 
The lab is estimated to be between {65, 75} F, or {18.3, 23.8} C.

Plot[Re[Y[T,110]],{T,18,24},PlotRange->{{18,24},{15,21}},Frame->True,PlotStyle->{Red},FrameLabel->{"Temperature, C","Modulus, MPa"}]

Plot[Im[Y[T,110]]/Re[Y[T,110]],{T,18,24},PlotRange->{{18,24},{.6,1.}},Frame->True,PlotStyle->{Blue},FrameLabel->{"Temperature, C","Loss Factor, MPa"}]

Sqrt[Re[Y[18.3,110]]/Re[Y[23.8,110]]]

(Im[Y[18.3,110]]/Re[Y[18.3,110]])

(Im[Y[23.8,110]]/Re[Y[23.8,110]])

(Im[Y[18.3,110]]/Re[Y[18.3,110]])/(Im[Y[23.8,110]]/Re[Y[23.8,110]])

As the temperature decreases, the modulus and resonant frequency of the NMBD increases. This increase in frequency reduces the coupling of the NMBD to the blade-spring’s first internal resonance. However as the temperature decreases, the damping factor increases, which tends to mitigate the effect of the decreased coupling.