CRYO PUMP RADIANT INTERCHANGE

Cryo Pump Properties

Component Dimensions

Dia=1.22;          (* m *)
Ltrap=3.7;        (*large cryo-pump, m *)
Lshield=1.5;   (* m *)
Lbt=20;               (* m *)

radius=Dia/2;
L=Ltrap+2 (Lshield+Lbt);   (* overall length, m *)

Component Emissivities

eend=0.9;   (* emissivity of the bt ends *)
ebt=0.5;    (* emissivity of the beam tube *)
eshield=0.06;    (* emissivity of the shields *)
etrap=1.0;    (* emissivity of the cold trap *)

Component Temperatures

Tend=295;
Tbt=295;
Tshield=295;
Ttrap=80;

Cryo Pump Model Parameters

Segmentation

ds = segmentation distance (m)
ntrap = number of segments for the cold trap surface
nshield = number of segments for each shield surface
nbt = number of segments for each beam tube surface

ds=0.15;
ntrap=Floor[Ltrap/ds]
nshield=Floor[Lshield/ds]
nbt=Floor[Lbt/ds]
n=2+2 (nbt+nshield)+ntrap

Segmented Surface Area, Position, Length, Emissivity & Temperature

A=Table[0,{n}];
emiss=A;
T=A;
x=A;
s=A;
A[[1]]=Pi Dia^2/4;
A[[n]]=A[[1]];
emiss[[1]]=eend;
emiss[[n]]=emiss[[1]];
T[[1]]=Tend;
T[[n]]=T[[1]];
x[[1]]=0;
x[[n]]=L;
s[[1]]=0;
s[[n]]=0;

As=Pi Dia Lbt/nbt;
es=ebt;
Ts=Tbt;
ss=Lbt/nbt;
Do[
A[[i]]=As;
emiss[[i]]=es;
T[[i]]=Ts;
s[[i]]=ss;
x[[i]]=x[[i-1]]+s[[i-1]];
A[[i+nbt+ntrap+2 nshield]]=As;
emiss[[i+nbt+ntrap+2 nshield]]=es;
T[[i+nbt+ntrap+2 nshield]]=Ts;
s[[i+nbt+ntrap+2 nshield]]=ss;
x[[i+nbt+ntrap+2 nshield]]=x[[i]]+Lbt+Ltrap+2 Lshield,{i,2,nbt+1}
];
As=Pi Dia Lshield/nshield;
es=eshield;
Ts=Tshield;
ss=Lshield/nshield;
Do [
A[[i]]=As;
emiss[[i]]=es;
T[[i]]=Ts;
s[[i]]=ss;
x[[i]]=x[[i-1]]+s[[i-1]];
A[[i+nshield+ntrap]]=As;
emiss[[i+nshield+ntrap]]=es;
T[[i+nshield+ntrap]]=Ts;
s[[i+nshield+ntrap]]=ss;
x[[i+nshield+ntrap]]=x[[i]]+Lshield+Ltrap,{i,nbt+2,nbt+nshield+1}
];
As=Pi Dia Ltrap/ntrap;
es=etrap;
Ts=Ttrap;
ss=Ltrap/ntrap;
Do [
A[[i]]=As;
emiss[[i]]=es;
T[[i]]=Ts;
s[[i]]=ss;
x[[i]]=x[[i-1]]+s[[i-1]], {i,nbt+nshield+2,nbt+nshield+ntrap+1}
];

View Factors

F=Table[0,{n},{n}];

Disk-Disk View Factors

N.B. : Concentric, r1 and r2 are radii, h = distance between disks

Fdd[r1_,r2_,h_]:=If[h==0,1,With[{X=1+(1+(r2/h)^2)/(r1/h)^2},1/2 (X-Sqrt[X^2-4 (r2/r1)^2])]];

Left End Disk (1) - Right End Disk (n) :

F[[1,n]]=Fdd[Dia/2,Dia/2,L];

Disk-Interior Cylinder View Factors

N.B. : Concentric, r1 = disk radius, r2 = cylinder radius, r1 <= r2, h1 = distance from disk to near end of cylinder, h2 = distance from disk to far end of cylinder

Fdc[r1_,r2_,h1_,h2_]:=Fdd[r1,r2,h1]-Fdd[r1,r2,h2];

Left End Disk (1) - Cylindrical Segments (2 --> n-1) and by symmetry, Cylindrical Segments (2 --> n-1) - Right End Disk (n) :

Do [F[[1,i]]=Fdc[radius,radius,x[[i]],x[[i]]+s[[i]]];
j=n-i+1;
F[[j,n]]=F[[1,i]] A[[n]]/A[[j]],
{i,2,n-1}];

Interior Cylinder Self-View Factors

N.B. : r = radius, l = cylinder length

Fcself[r_,l_]:=1-(r/l) Fdc[r,r,0,l];

Cylindrical Segments (i) - Cylindrical Segments (i), for i = {2,n-1} :

Do [
F[[i,i]]=Fcself[radius,s[[i]]],
{i,2,n-1}
];

Interior Equal-Diameter Concentric Cylinder View Factors

N.B. : r = radius, l1 = cylinder 1 length, l2 = cylinder 2 length, h = separation distance

Fceq[r_,l1_,l2_,h_]:=(Fdc[r,r,h,l1+h]-Fdc[r,r,l2+h,l2+l1+h]) (r/(2 l1));

Cylindrical Segments (i) - Cylindrical Segments (j), for i,j = {2,n-1} :

Ftemp=Table[0,{n},{n}];

Do [
Do [
F[[i,j]]=Fceq[radius,s[[i]],s[[j]],x[[j]]-x[[i]]-s[[i]]];
Ftemp[[i,j]]=F[[i,j]],
{j,i+1,n-1}
],
{i,2,n-2}
];

Reciprocity

Do [
Do [
F[[i,j]]=F[[j,i]] A[[j]]/A[[i]],
{j,1,i-1}],
{i,2,n}];

Plot View Factors

xmid=x+s/2-L/2;

ListLogPlot[{Transpose[Partition[Join[xmid,F[[1]]],n]],Transpose[Partition[Join[xmid,F[[10]]],n]],Transpose[Partition[Join[xmid,F[[66]]],n]],Transpose[Partition[Join[xmid,F[[70]]],n]],Transpose[Partition[Join[xmid,F[[Floor[n/2]]]],n]],Transpose[Partition[Join[xmid,F[[n]]],n]]},Joined->True,PlotRange->{All,All}]

Check that the view factors sum to unity by summing accross the rows :

Total[F,{2}]

Radiant Exchange Solution

one=Table[1,{n}];
a = IdentityMatrix[n]-Dot[DiagonalMatrix[(one-emiss)],F];

stefanBoltzmann=5.6696 10^-8;   (* W/m^2/K^4 *)
b=stefanBoltzmann emiss T^4;

qo=Inverse[a].b;

q=qo-F.qo //N;

Q=Dot[DiagonalMatrix[A],(qo-F.qo)] //N;

Qends=Q[[1]]+Q[[n]]

Qbts=Sum[Q[[i]],{i,2,nbt+1}]+Sum[Q[[i]],{i,nbt+ntrap+2 nshield+2,n-1}]

Qshields=Sum[Q[[i]],{i,nbt+2,nbt+nshield+1}]+Sum[Q[[i]],{i,nbt+nshield+ntrap+2,nbt+ntrap+2 nshield+1}]

Qtrap=Sum[Q[[i]],{i,nbt+nshield+2,nbt+nshield+ntrap+1}]

xmid=x+s/2-L/2;

ListLinePlot[Transpose[Partition[Join[xmid,q],n]],PlotRange->{All,All}]

ListLinePlot[Transpose[Partition[Join[xmid,q],n]],PlotRange->{{-5,5},All}]

ListLinePlot[Transpose[Partition[Join[xmid,Q],n]],PlotRange->{{-10,10},All}]

Tabulated Results

Long Cryo-Pump

1.2 m diameter
3.7 m long cold trap
nominally 1.52 m long shields (liners)
trap emissivity = 1.0 (ice)
shield emissivity = 0.06 (diffuse)
beam tube model length = 20 m
shield emissivity = 0.06
nbt = 20
nshield = 5
ntrap = 10
n = 62
Qtrap = 504 W
q (W/m^2) vs Xmid (m)

shield emissivity = 0.05
nbt = 20
nshield = 5
ntrap = 10
n = 62
Qtrap = 817 W (823 W when Lshield = 3 m)
q (W/m^2) vs Xmid (m)

Used nshield = 10, for a no-shield resulting Q=815 W in the following sensitivity calculations to shield emissivity and length:

emissShield={0.06,0.10};

Qlong={{{0,815},{0.25,728},{0.5,652},{1.0,557},{1.25,526},{2,470},{4,423}},{{0,815},{0.25,738},{0.5,670},{1,590},{1.5,548},{2,525}}};

ListLinePlot[Qlong,PlotRange->All,Frame->True,RotateLabel->False,FrameLabel->{"Shield Length (m)","Load (W)"}]

Heat Load (w) on the inner surface of the cryo-pump (cold trap) for the “long” (3.7 m) cryo-pump, as a function of shield length (m) parameterized by emissivity (0.06 and 0.10).

Short Cryo-Pump

1.2 m diameter
1.2 m long cold trap
1 m long shields (liners)
trap emissivity = 1.0 (ice)
shield emissivity = 0.06 (diffuse)
beam tube model length = 10 m
shield emissivity = 0.06
nbt = 20
nshield = 5
ntrap = 10
n = 62
Qtrap = 489 W
q (W/m^2) vs Xmid (m)

shield emissivity = 0.05
nbt = 20
nshield = 5
ntrap = 10
n = 62
Qtrap = 702 W (when Lshield = 1 m)
Qtrap = 708 W (when Lshield = 3 m)
q (W/m^2) vs Xmid (m)

Used 10 segments for the shield when the emissivityof the shield was set to 0.2

emissShield={0.06,0.10, 0.20};

Qshort={{{0,702},{0.25,622},{0.5,562},{1.0,489},{1.25,465},{2,424},{4,398}},{{0,702},{0.25,630},{0.5,578},{1,516},{2,466}},
{{0,703},{0.25,650},{0.5,614},{1,576},{2,553},{4,550}}};

ListLinePlot[Qshort,PlotRange->All,Frame->True,RotateLabel->False,FrameLabel->{"Shield Length (m)","Load (W)"}]

Heat Load (W) on the inner surface of the cryo-pump (cold trap) for the “short” (1.2 m) cryo-pump, as a function of shield length (m) parameterized by emissivity (0.06, 0.10 and 0.20).